;W595 SW-R3EF001
;Displays a process of transmission through BT in the status bar.
;Only works if the window "Sending" is minimalized.
;v 1.0
;(c) MaPkiZzz aka Vital
;(p) jamesbond22

include "x.inc"

patchbody = 0x11F19B70




org 0x11770D54
dw drawing_in_statusrow+1

org 0x11B08620
dw Send1+1

org 0x11B08658
dw Send2+1

;Remove message "Sent" in the end sending the file via Bluetooth (needed for A2)
org 0x108A0408
MOV R1, 0
ADD R0, R5, 0
BL 0x108A0350
B 0x108A0464

;------------------------------------------------------------------------------------------------------------;
;------------------------------------------------------------------------------------------------------------;
org patchbody
drawing_in_statusrow:
PUSH {R4,LR}
LDR R0, is_ObExSendBook
BL FindBook
ADD R4, R0, 0
BEQ nothing
BL to_BOOKDISPLAY_GetTopBook
CMP R4, R0
BEQ nothing
MOVL R0, 0x440 ;OK
ADD R0, R4, R0
LDR R1, [R0,4]
LDR R0, [R0]
ASR R2, R1, 9
LSR R2, R2, 0x16
ADD R1, R2, R1
ASR R1, R1, 0xA
ASR R2, R0, 9
LSR R2, R2, 0x16
ADD R0, R2, R0
ASR R0, R0, 0xA
BL drawing
nothing:
POP {R4,PC}

Send1:
PUSH {R0-R7,LR}
LDR R7, off_Send1
BLX R7
BL notonlyStandby
POP {R0-R7,PC}

Send2:
PUSH {R0-R7,LR}
LDR R7, off_Send2
BLX R7
BL notonlyStandby
POP {R0-R7,PC}

notonlyStandby:
PUSH {LR}
LDR R0, _HEAP
LDR R0, [R0]
MOV R1, 0
BL InvalidateRect
POP {PC}

drawing:
PUSH {R4,LR}
adr R2, _dword
SUB SP, SP, 0x40
PUSH {R1}
ADD R3, R0, 0
ADD R0, SP, 4
MOV R1, 0x20
BL intsnwprintf
LDR R0, dword_OutlineColor
LDR R1, dword_BackgroundColor
PUSH {R0,R1}
MOV R3, 0x16
MOV R2, 0x9D
MOV R0, 0x2D
MOV R1, 3
BL DrawBackground
LDR R2, NULL
MOV R1, 0
ADD R0, SP, 0xC
BL Str2ID
ADD R4, R0, 0
MOV R0, 0x18
BL SetFont
MOV R2, 0
LDR R1, dword_TextColor
MOV R0, 5
PUSH {R0-R2}
MOV R2, 0x3C
MOV R0, 0x9B
MOV R1, 7
PUSH {R0-R2}
MOV R3, 1
ADD R0, R4, 0
MOV R1, 2
MOV R2, 0x2F
BL DrawString
ADD SP, SP, 0x24
ADD R0, R4, 0
BL TextFree
ADD SP, SP, 0x40
POP {R4,PC}
;------------------------------------------------------------------------------------------------------------;
;------------------------------------------------------------------------------------------------------------;
FindBook:
        LDR R3, off_FindBook
        BX R3

to_BOOKDISPLAY_GetTopBook:
        LDR R3, off_to_BOOKDISPLAY_GetTopBook
        BX R3

strcmp:
        LDR R3, off_strcmp
        BX R3

Str2ID:
        LDR R3, off_Str2ID
        BX R3
        
SetFont:
        LDR R3, off_SetFont
        BX R3

TextFree:
        LDR R3, off_TextFree
        BX R3

InvalidateRect:
        LDR R3, off_InvalidateRect
        BX R3

DrawString:
        PUSH {R3}
        LDR R3, off_DrawString
        MOV R12, R3
        POP {R3}
        BX R12

DrawBackground:
        PUSH {R3}
        LDR R3, off_DrawBackground
        MOV R12, R3
        POP {R3}
        BX R12

intsnwprintf:
        PUSH {R3}
        LDR R3, off_intsnwprintf
        MOV R12, R3
        POP {R3}
        BX R12

;------------------------------------------------------------------------------------------------------------;
align 4
_dword du "%d/%d KB",0
align 4
NULL dw 0xFFFF
off_TextFree dw 0x10F62178+1
off_DrawString dw 0x109CC0B8+1
off_SetFont dw 0x109CCC38+1
off_Str2ID dw 0x10F61E3C+1
off_DrawBackground dw 0x109CBD2C+1
off_intsnwprintf dw 0x106F8694+1
off_strcmp dw 0x106F8468+1
off_to_BOOKDISPLAY_GetTopBook dw 0x10DF020C+1
off_FindBook dw 0x10DEE964+1
is_ObExSendBook dw 0x1089F4A0+1
off_Send1 dw 0x1089FF99
off_Send2 dw 0x1089FFFD
_HEAP dw 0x4BBC51A8
off_InvalidateRect dw 0x109C8968+1 ;OK
dword_OutlineColor dw 0xFF959595
dword_BackgroundColor dw 0x90000000
dword_TextColor dw 0xFFFF9933